[VBA Excel]

Option Explicit

Private CurrentLics As Collection
Private RowsToDelete As Collection

Sub BrisiStare()
    Dim tmpLic As License
    Dim IDs As Range
    Dim ID As Range
    Dim Lic As Range
    Dim CurrentID As String
    Dim CurrentL As String
    
    Set CurrentLics = New Collection
    Set RowsToDelete = New Collection
    Set IDs = Selection
    
    ' Vse oznacene vrstice
    For Each ID In IDs
        ' Prva vrstica
        If LenB(CurrentID) = 0 Then CurrentID = ID.Value
        
        Set Lic = ID.Offset(0, 1)
        If LenB(CurrentL) = 0 Then CurrentL = Lic.Value
        
        ' Ce je ID ali Licenca drugacna od prejsnje
        If CurrentL <> Lic.Value Or CurrentID <> ID.Value Then
            ' Oznaci vse razen najnovejse za brisanje
            DeleteOlderLicenses
            CurrentL = Lic.Value
            CurrentID = ID.Value
        End If
        
        ' Dodaj trenutno vrstico v zbirko
        Set tmpLic = New License
        tmpLic.EndDate = CDate(Lic.Offset(0, 2).Value)
        tmpLic.RowOffset = ID.Row
        
        CurrentLics.Add tmpLic
    Next ID
    
    ' Oznaci za brisanje
    DeleteOlderLicenses
    ' Brise vse vrstice, oznacene za brisanje
    DeleteAll
End Sub

Private Sub DeleteOlderLicenses()
    Dim tmpLic As License
    Dim latestDate As Date
    Dim i As Long
    
    If Not CurrentLics Is Nothing Then
        ' Poisce zadnji datum
        For Each tmpLic In CurrentLics
            If latestDate = 0 Then latestDate = tmpLic.EndDate
            If tmpLic.EndDate > latestDate Then
                latestDate = tmpLic.EndDate
            End If
        Next tmpLic
        
        ' Za brisanje oznaci vse vrsice, kjer je datum manjsi od zadnjega
        For Each tmpLic In CurrentLics
            If tmpLic.EndDate <> latestDate Then
                RowsToDelete.Add tmpLic.RowOffset
            End If
        Next tmpLic
        
        Set CurrentLics = New Collection
    End If
End Sub

Private Sub DeleteAll()
    Dim i As Long
    
    ' Brise vse oznacene vrstice v obratnem vrstnem redu
    If Not RowsToDelete Is Nothing Then
        For i = RowsToDelete.Count To 1 Step -1
            Rows(RowsToDelete(i)).Delete
        Next i
    End If
    Set RowsToDelete = Nothing
End Sub

Option Explicit

Public RowOffset As Long
Public EndDate As Date