VB + sernum diska

A kdo slučajno ve, kako bi v VB6 dobil v spremenljivko serijsko številko diska?

Declare Function GetVolumeInformation Lib "kernel32.dll" Alias "GetVolumeInformationA" (ByVal lpRootPathName As String, ByVal lpVolumeNameBuffer As String, ByVal nVolumeNameSize As Integer, lpVolumeSerialNumber As Long, lpMaximumComponentLength As Long, lpFileSystemFlags As Long, ByVal lpFileSystemNameBuffer As String, ByVal nFileSystemNameSize As Long) As Long




Function GetInfo(sRoot As String) As String
Dim VSN As Long
Dim N As Long
Dim S1 As String
Dim S2 As String

S1 = Space(255)
S2 = Space(255)

N = GetVolumeInformation(sRoot, S1, Len(S1), VSN, 0, 0, S2, Len(S2))
S1 = StringFromBuffer(S1)
S2 = StringFromBuffer(S2)
GetInfo = "Disk " & sRoot & vbCrLf & "Volume:" & S1 & vbCrLf & "Aloc: " & S2 & vbCrLf & "Serial No: " & Hex(VSN)
End Function


Sub main()
MsgBox GetInfo("c:/")
End Sub

Public Function StringFromBuffer(Buffer As String) As String
Dim nPos As Long

nPos = InStr(Buffer, vbNullChar)
If nPos > 0 Then
StringFromBuffer = Left$(Buffer, nPos - 1)
Else
StringFromBuffer = Buffer
End If
End Function

Probaj to

Ni blema :)