access -> word ali excel

Kaj pa če bi naredil kar formo v Accessu?
lp

Potem naredi wordov template s formo, kjer bo uporabnik izbral, kaj in od kod bi prenašal podatke in makro za prenos nekako takole:

Sub CopyTable()
On Error GoTo CopyTable_E
Dim cnn As New ADODB.connection
Dim rst As New ADODB.Recordset
Dim tbl As Table
Dim flds As ADODB.Fields
Dim fld As ADODB.Field
Dim i&

With cnn
.ConnectionString = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=D:\My Documents\test.mdb"
.Open
End With
With rst
.ActiveConnection = cnn
.Source = "select * from TEST"
.CursorType = adOpenForwardOnly
.LockType = adLockReadOnly
.Open
Set flds = .Fields
End With

Set tbl = ActiveDocument.Tables.Add(Range:=Selection.Range, NumRows:=1, NumColumns:=flds.Count, DefaultTableBehavior:=wdWord9TableBehavior, AutoFitBehavior:=wdAutoFitFixed)
With tbl
' glava
For Each fld In flds
i = i + 1
.Rows(1).Cells(i).Select
Selection.TypeText Text:=fld.Name
Next fld
' polni podatke
While Not rst.EOF
Selection.InsertRowsBelow 1
i = 0
For Each fld In flds
i = i + 1
.Rows(.Rows.Count).Cells(i).Select
Selection.TypeText Text:=fld.Value
Next fld
rst.MoveNext
Wend
.Rows(1).Select
Selection.Font.Bold = wdToggle
End With

CopyTable_X:
On Error Resume Next
rst.Close
cnn.Close
Set rst = Nothing
Set cnn = Nothing
Exit Sub
CopyTable_E:
MsgBox Err.Description
Resume CopyTable_X
End Sub

Templatu moraš referencirati "Microsoft ActiveX Data Objects"

lp

Aja, pa če nočeš, da bo procedura vidna v seznamu makrojev (t.j. poganja se npr. iz forme, sicer pa je uporabnik ne more pognati), ji daj en dummy argument.